root/trunk/level/level.ahk

;
; level
; Language:       English
; Platform:       Win XP / Vista tested
; Author:         S.van Dragt <sander.vandragt@gmail.com>
;
; Script Function:
;       Commandline script flatttening a series of folders into a final folder
;
version = 1.07.04

#NoEnv
SendMode Input
#NoTrayIcon
#ErrorStdOut
SetBatchLines, -1  ; Make the operation run at maximum speed.
subfolders      = 0
individual      = n
overwrite       = n
overwriteolderonly = n
TotalFilesCopied = 0

FileAppend, Level %version% by Sander van Dragt <sander.vandragt@gmail.com>`n, *


; read in parameters
; if parameters is not a switch then it's a path
If 0 < 2
{
        MsgBox,0,Level %version% by Sander van Dragt <sander.vandragt@gmail.com>,Level copies files from several sources into a flat folder. Only works from a command prompt.`n`nUse it to for example to copy all your music from 3 sources into one long list of files, or make sure you have the latest version of all your pictures in one place. `n`nSyntax: level `[-s`,-oo`,-o`] `<source`> `[more source`] `<destination`> |cat`n`t-s = level subfolders`n`t-o = overwrite existing files `(-o or -oo`)`n`t-oo = overwrite older existing files only `(-oo or -o`)`n`t|cat = output to command prompt (as opposed to stdout)`n`nExample:`nlevel -o -s c:\temp\1\*.* c:\temp\2\*.* d:\temp\output |cat`n`nLevel requires cat.exe from the UnxUtils project on SourceForge.net (http://sourceforge.net/projects/unxutils/) to display anything on the commandline.
}
else 
{
        Loop, %0%  ; For each parameter:
        {

                        

                param := %A_Index%
                if param = -s 
                {
                        subfolders = 1
                        FileAppend, SWITCH: subfolders leveled`n, *
                }
                else if param = -i 
                {
                        individual = y
                        FileAppend, SWITCH: individual prompting`n, *
                }
                else if param = -oo
                {
                        overwriteolderonly = y
                        FileAppend, SWITCH: overwrite older files`n, *
                }
                else if param = -o 
                {
                        overwrite = y
                        FileAppend, SWITCH: overwrite existing files`n, *
                }
                else 
                {
                        ;get the path and add it in
                        Loop %param%
                                LongPath = %A_LoopFileLongPath%
                        FolderCount += 1 
                        Folder%FolderCount% := %A_Index%  
                }
        }
        CopyDest := Folder%FolderCount%
        FileAppend, DESTINATION: %CopyDest%`n, *
        IfNotExist, %CopyDest%
                FileCreateDir, %CopyDest%

        Loop %FolderCount%
        {
            ; The following line uses the := operator to retrieve an array element:
                if A_Index < %FolderCount% 
                {
                        CopySourcePattern := Folder%A_Index%  ; A_Index is a built-in variable.
                        GoSub, CopyIfNewer
                }
        }
}
ExitApp

; Example #5: Copy only the source files that are newer than their counterparts
; in the destination:
CopyIfNewer:
        NewFilesCopied = 0
        FileAppend, `nSOURCE: %CopySourcePattern%`n, *
        ; Caller has set the variables CopySourcePattern and CopyDest for us.
        
        Loop, %CopySourcePattern%,0,%subfolders%
        {
                Sleep, 10
                copy_it = n
                StringReplace, FileNoSpaces, A_LoopFileName, %A_Space%,, All ;Take out spaces
                
                IfNotExist, %CopyDest%\%FileNoSpaces% ; Always copy if target file doesn't yet exist.
                        copy_it = y
                else
                {
                        ; File exists
                        if overwrite = y 
                        {
                                if overwriteolderonly = n
                                {
                                        copy_it = y
                                }
                                else
                                {
                                        FileGetTime, time, %CopyDest%\%FileNoSpaces%
                                        EnvSub, time, %A_LoopFileTimeModified%, seconds  ; Subtract the source file's time from the destination's.
                                        if time < 0  ; Source file is newer than destination file.
                                                copy_it = y
                                }
                        }
                }
                
                if copy_it = y
                {
                        NewFilesCopied += 1
                        FileCopy, %A_LoopFileFullPath%, %CopyDest%\%FileNoSpaces%, 1   ; Copy with overwrite=yes
                        if ErrorLevel
                                MsgBox, Could not copy "%A_LoopFileFullPath%" to "%CopyDest%\%FileNoSpaces%".
                        FileAppend, %A_LoopFileFullPath%`n --> %CopyDest%\%FileNoSpaces%`n, *
                }
        }
        TotalFilesCopied += NewFilesCopied
        FileAppend, DONE: %NewFilesCopied%/%TotalFilesCopied% files copied`n, *
Return

GuiClose:
ExitApp